src/sicp/metacircular2.rkt

   1 #lang racket
   2
   3 (require (rename-in racket/base
   4                     (apply apply-in-underlying-scheme)
   5                     (eval eval-in-underlying-scheme)))
   6
   7 (define (self-evaluating? expr)
   8   (match expr
   9     [(? number? expr) #t]
  10     [(? char? expr) #t]
  11     [(? string? expr) #t]
  12     [_ #f]))
  13
  14 (define (variable? expr) (symbol? expr))
  15
  16
  17 ;; sequence
  18 (define (eval-sequence exps env)
  19   (cond ((last-exp? exps) (eval (first-exp exps) env))
  20         (else (eval (first-exp exps) env)
  21               (eval-sequence (rest-exps exps) env))))
  22
  23 ;; begin
  24 (define (last-exp? seq) (null? (cdr seq)))
  25 (define (first-exp seq) (car seq))
  26 (define (rest-exps seq) (cdr seq))
  27
  28 ;; lambda
  29 (define (make-lambda parameters body)
  30   (cons 'lambda (cons parameters body)))
  31
  32 ;; environment data structures
  33 (define (enclosing-environment env) (cdr env))
  34 (define (first-frame env) (car env))
  35 (define the-empty-environment '())
  36
  37 (define (make-frame variables values)
  38   (let ([ht (make-hash)])
  39     (for-each (lambda (var val)
  40                 (hash-set! ht var val))
  41               variables
  42               values)
  43     ht))
  44
  45 (define (frame-variables frame)
  46   (hash-keys frame))
  47
  48 (define (frame-values frame)
  49   (hash-values frame))
  50
  51 (define (add-binding-to-frame! var val frame)
  52   (hash-set! frame var val))
  53
  54 ;; environment is a list of frames, most recent being the last
  55 ;; one consed into the list
  56 (define (extend-environment vars vals base-env)
  57   (let ([frame (make-frame vars vals)])
  58     (cons frame base-env)))
  59
  60 (define (lookup-variable-value var env)
  61   (if (eq? env the-empty-environment)
  62       (error "unbound variable:" var)
  63       (let ([frame (first-frame env)])
  64         (let ([value (hash-ref frame var (lambda () (lookup-variable-value var (enclosing-environment env))))])
  65           (if (eq? value '*unassigned*)
  66               (error "evaluating a variable that is not assigned a value -- " var)
  67               value)))))
  68
  69 (define (set-variable-value! var val env)
  70   (if (eq? env the-empty-environment)
  71       (error "unbound variable")
  72       (let ([frame (first-frame env)])
  73         (if (hash-has-key? frame var)
  74             (hash-set! frame var val)
  75             (set-variable-value! var val (enclosing-environment env))))))
  76
  77 (define (define-variable! var val env)
  78   (let ([frame (first-frame env)])
  79     (if (hash-has-key? frame var)
  80         (hash-set! frame var val)
  81         (add-binding-to-frame! var val frame))))
  82
  83 ;; primitive procedure
  84 (define (primitive-implementation proc) (cadr proc))
  85
  86 (define primitive-procedures
  87   (list (list 'car car)
  88         (list 'cdr cdr)
  89         (list 'cons cons)
  90         (list 'null? null?)
  91         (list 'list list)
  92         (list '+ +)
  93         (list '- -)
  94         (list '* *)
  95         (list '/ /)
  96         (list '= =)))
  97
  98 (define (primitive-procedure-names)
  99   (map car primitive-procedures))
 100
 101 (define (primitive-procedure-objects)
 102   (map (lambda (proc) (list 'primitive (cadr proc)))
 103        primitive-procedures))
 104
 105 (define (apply-primitive-procedure proc args)
 106   (apply-in-underlying-scheme
 107    (primitive-implementation proc) args))
 108
 109 ;; global env
 110 (define (setup-environment)
 111   (let ((initial-env
 112          (extend-environment (primitive-procedure-names)
 113                              (primitive-procedure-objects)
 114                              the-empty-environment)))
 115     (define-variable! 'true true initial-env)
 116     (define-variable! 'false false initial-env)
 117     initial-env))
 118
 119 (define the-global-environment (setup-environment))
 120
 121 ;; application
 122 (define (list-of-values exps env)
 123   (if (no-operands? exps)
 124       '()
 125       (cons (eval (first-operand exps) env)
 126             (list-of-values (rest-operands exps) env))))
 127
 128 (define (no-operands? ops) (null? ops))
 129 (define (first-operand ops) (car ops))
 130 (define (rest-operands ops) (cdr ops))
 131
 132 ;; compound procedure
 133 (define (make-procedure params body env)
 134   (list 'procedure params (scan-out-definitions body) env))
 135
 136 (define (procedure-parameters p) (cadr p))
 137 (define (procedure-body p) (scan-out-definitions (caddr p)))
 138 (define (procedure-environment p) (cadddr p))
 139
 140 (define (apply procedure arguments)
 141   (match procedure
 142     [`(primitive ,f ...)  (apply-primitive-procedure procedure arguments)]
 143     [`(procedure ,f ...)  (eval-sequence
 144                        (procedure-body procedure)
 145                        (extend-environment
 146                         (procedure-parameters procedure)
 147                         arguments
 148                         (procedure-environment procedure)))]
 149     [_                (error "Unknown procedure type -- APPLY" procedure)]))
 150
 151 ;; truth
 152 (define (true? x)
 153   (not (eq? x false)))
 154
 155 (define (false? x)
 156   (eq? x false))
 157
 158 ;; cond
 159 (define (cond->if clauses)
 160   (define (seq->exp actions)
 161     (if (empty? (cdr actions))
 162         (car actions)
 163         `(begin ,@actions)))
 164   (if (empty? clauses)
 165       'false
 166       (let ([clause (car clauses)])
 167         (match clause
 168           [`(else ,action ...) (seq->exp action)]
 169           [`(,pred ,action ...) `(if ,pred
 170                                      ,(seq->exp action)
 171                                      ,(cond->if (cdr clauses)))]))))
 172
 173 ;; let
 174 (define (let->combination lexpr)
 175   (match-let* ([`(let ,bindings ,body ..1) lexpr]
 176                [`((,var ,val) ...) bindings])
 177     `((lambda ,var ,@body) ,@val)))
 178
 179 ;; let*
 180 (define (let*->nested-lets lexpr)
 181   (match lexpr
 182     [`(let* (,first-binding ,rest-bindings ...) ,body ..1)
 183      `(let (,first-binding) ,(let*->nested-lets `(let* ,rest-bindings ,@body)))]
 184      [`(let* () ,body ..1) `(let () ,@body)]))
 185
 186 ;; internal definitions
 187 (define (scan-out-definitions body)
 188   (match body
 189     [`((define ,var ,e) ..1 ,rest)
 190      `((let ,(map (lambda (v) (list (car v) ''*unassigned*)) var)
 191         ,@(map (lambda (v e) `(set! ,(car v) (lambda ,(cdr v) ,e))) var e)
 192         ,rest))]
 193     [_  body]))
 194
 195 ;; letrec
 196 (define (letrec->combination lexpr)
 197   (match lexpr
 198     [`(letrec (,bindings ...) ,body ..1)
 199      `(let ,(map (lambda (v) (list (car v) ''*unassigned*)) bindings)
 200         ,@(map (lambda (binding)
 201                  (let ([name (car binding)]
 202                        [value (cadr binding)])
 203                    `(set! ,name ,value)))
 204                bindings)
 205         ,@body)]))
 206
 207 ;; eval
 208 (define (eval exp env)
 209   ;; use this display statement to visualize the recursive evaluation process
 210   ;;(display (format "~s~%" exp))
 211   (match exp
 212     [(? self-evaluating? exp) exp]
 213     [(? variable? exp) (lookup-variable-value exp env)]
 214     [`(quote ,x) x]
 215     [`(set! ,var ,val) (set-variable-value! var (eval val env) env)]
 216     [`(define ,(? (lambda (x) (not (pair? x))) var) ,b) (define-variable! var (eval b env) env)]
 217     [`(define ,(? pair? var) ,b ..1) (define-variable! (car var) (eval (make-lambda (cdr var) b) env) env)]
 218     [`(if ,pred ,consequent ,alternative) (if (true? (eval pred env)) (eval consequent env) (eval alternative env))]
 219     [`(lambda ,parameters ,body ..1) (make-procedure parameters body env)]
 220     [`(begin ,exp ...) (eval-sequence exp env)]
 221     [`(cond ,clauses ...) (eval (cond->if clauses) env)]
 222     [`(let ,bindings ,body ..1) (eval (let->combination exp) env)]
 223     [`(let* ,bindings ,body ..1) (eval (let*->nested-lets exp) env)]
 224     [`(letrec ,bindings ,body ..1) (eval (letrec->combination exp) env)]
 225     [(list f x ...) (apply (eval f env) (list-of-values x env))]
 226     [_ (error "unable to evaluate expression -- EVAL " exp)]))
 227
 228
 229 (define (interpret)
 230   (let loop ([input (read)]
 231              [env the-global-environment])
 232     (let ([output (eval input env)])
 233       (display output)
 234       (loop (read) env))))
 235
 236 (define (t expr)
 237   (let ([t1 (current-inexact-milliseconds)])
 238     (eval expr the-global-environment)
 239     (displayln (- (current-inexact-milliseconds) t1))))