src/sicp/metacircular2.rkt

   1 #lang racket
   2
   3 (require (rename-in racket/base
   4                     (apply apply-in-underlying-scheme)
   5                     (eval eval-in-underlying-scheme)))
   6
   7 (provide (all-defined-out))
   8
   9 (define (self-evaluating? expr)
  10   (match expr
  11     [(? number? expr) #t]
  12     [(? char? expr) #t]
  13     [(? string? expr) #t]
  14     [_ #f]))
  15
  16 (define (variable? expr) (symbol? expr))
  17
  18
  19 ;; sequence
  20 (define (eval-sequence exps env)
  21   (cond ((last-exp? exps) (eval (first-exp exps) env))
  22         (else (eval (first-exp exps) env)
  23               (eval-sequence (rest-exps exps) env))))
  24
  25 ;; begin
  26 (define (last-exp? seq) (null? (cdr seq)))
  27 (define (first-exp seq) (car seq))
  28 (define (rest-exps seq) (cdr seq))
  29
  30 ;; lambda
  31 (define (make-lambda parameters body)
  32   (cons 'lambda (cons parameters body)))
  33
  34 ;; environment data structures
  35 (define (enclosing-environment env) (cdr env))
  36 (define (first-frame env) (car env))
  37 (define the-empty-environment '())
  38
  39 (define (make-frame variables values)
  40   (let ([ht (make-hash)])
  41     (for-each (lambda (var val)
  42                 (hash-set! ht var val))
  43               variables
  44               values)
  45     ht))
  46
  47 (define (frame-variables frame)
  48   (hash-keys frame))
  49
  50 (define (frame-values frame)
  51   (hash-values frame))
  52
  53 (define (add-binding-to-frame! var val frame)
  54   (hash-set! frame var val))
  55
  56 ;; environment is a list of frames, most recent being the last
  57 ;; one consed into the list
  58 (define (extend-environment vars vals base-env)
  59   (let ([frame (make-frame vars vals)])
  60     (cons frame base-env)))
  61
  62 (define (lookup-variable-value var env)
  63   (if (eq? env the-empty-environment)
  64       (error "unbound variable:" var)
  65       (let ([frame (first-frame env)])
  66         (let ([value (hash-ref frame var (lambda () (lookup-variable-value var (enclosing-environment env))))])
  67           (if (eq? value '*unassigned*)
  68               (error "evaluating a variable that is not assigned a value -- " var)
  69               value)))))
  70
  71 (define (set-variable-value! var val env)
  72   (if (eq? env the-empty-environment)
  73       (error "unbound variable")
  74       (let ([frame (first-frame env)])
  75         (if (hash-has-key? frame var)
  76             (hash-set! frame var val)
  77             (set-variable-value! var val (enclosing-environment env))))))
  78
  79 (define (define-variable! var val env)
  80   (let ([frame (first-frame env)])
  81     (if (hash-has-key? frame var)
  82         (hash-set! frame var val)
  83         (add-binding-to-frame! var val frame))))
  84
  85 ;; primitive procedure
  86 (define (primitive-implementation proc) (cadr proc))
  87
  88 (define primitive-procedures
  89   (list (list 'car car)
  90         (list 'cdr cdr)
  91         (list 'cons cons)
  92         (list 'null? null?)
  93         (list 'list list)
  94         (list '+ +)
  95         (list '- -)
  96         (list '* *)
  97         (list '/ /)
  98         (list '= =)))
  99
 100 (define (primitive-procedure-names)
 101   (map car primitive-procedures))
 102
 103 (define (primitive-procedure-objects)
 104   (map (lambda (proc) (list 'primitive (cadr proc)))
 105        primitive-procedures))
 106
 107 (define (apply-primitive-procedure proc args)
 108   (apply-in-underlying-scheme
 109    (primitive-implementation proc) args))
 110
 111 ;; global env
 112 (define (setup-environment)
 113   (let ((initial-env
 114          (extend-environment (primitive-procedure-names)
 115                              (primitive-procedure-objects)
 116                              the-empty-environment)))
 117     (define-variable! 'true true initial-env)
 118     (define-variable! 'false false initial-env)
 119     initial-env))
 120
 121 (define the-global-environment (setup-environment))
 122
 123 ;; application
 124 (define (list-of-values exps env)
 125   (if (no-operands? exps)
 126       '()
 127       (cons (eval (first-operand exps) env)
 128             (list-of-values (rest-operands exps) env))))
 129
 130 (define (no-operands? ops) (null? ops))
 131 (define (first-operand ops) (car ops))
 132 (define (rest-operands ops) (cdr ops))
 133
 134 ;; compound procedure
 135 (define (make-procedure params body env)
 136   (list 'procedure params (scan-out-definitions body) env))
 137
 138 (define (procedure-parameters p) (cadr p))
 139 (define (procedure-body p) (scan-out-definitions (caddr p)))
 140 (define (procedure-environment p) (cadddr p))
 141
 142 (define (apply procedure arguments)
 143   (match procedure
 144     [`(primitive ,f ...)  (apply-primitive-procedure procedure arguments)]
 145     [`(procedure ,f ...)  (eval-sequence
 146                        (procedure-body procedure)
 147                        (extend-environment
 148                         (procedure-parameters procedure)
 149                         arguments
 150                         (procedure-environment procedure)))]
 151     [_                (error "Unknown procedure type -- APPLY" procedure)]))
 152
 153 ;; truth
 154 (define (true? x)
 155   (not (eq? x false)))
 156
 157 (define (false? x)
 158   (eq? x false))
 159
 160 ;; cond
 161 (define (cond->if clauses)
 162   (define (seq->exp actions)
 163     (if (empty? (cdr actions))
 164         (car actions)
 165         `(begin ,@actions)))
 166   (if (empty? clauses)
 167       'false
 168       (let ([clause (car clauses)])
 169         (match clause
 170           [`(else ,action ...) (seq->exp action)]
 171           [`(,pred ,action ...) `(if ,pred
 172                                      ,(seq->exp action)
 173                                      ,(cond->if (cdr clauses)))]))))
 174
 175 ;; let
 176 (define (let->combination lexpr)
 177   (match-let* ([`(let ,bindings ,body ..1) lexpr]
 178                [`((,var ,val) ...) bindings])
 179     `((lambda ,var ,@body) ,@val)))
 180
 181 ;; let*
 182 (define (let*->nested-lets lexpr)
 183   (match lexpr
 184     [`(let* (,first-binding ,rest-bindings ...) ,body ..1)
 185      `(let (,first-binding) ,(let*->nested-lets `(let* ,rest-bindings ,@body)))]
 186      [`(let* () ,body ..1) `(let () ,@body)]))
 187
 188 ;; internal definitions
 189 (define (scan-out-definitions body)
 190   (match body
 191     [`((define ,var ,e) ..1 ,rest)
 192      `((let ,(map (lambda (v) (list (car v) ''*unassigned*)) var)
 193         ,@(map (lambda (v e) `(set! ,(car v) (lambda ,(cdr v) ,e))) var e)
 194         ,rest))]
 195     [_  body]))
 196
 197 ;; letrec
 198 (define (letrec->combination lexpr)
 199   (match lexpr
 200     [`(letrec (,bindings ...) ,body ..1)
 201      `(let ,(map (lambda (v) (list (car v) ''*unassigned*)) bindings)
 202         ,@(map (lambda (binding)
 203                  (let ([name (car binding)]
 204                        [value (cadr binding)])
 205                    `(set! ,name ,value)))
 206                bindings)
 207         ,@body)]))
 208
 209 ;; eval
 210 (define (eval exp env)
 211   ;; use this display statement to visualize the recursive evaluation process
 212   ;;(display (format "~s~%" exp))
 213   (match exp
 214     [(? self-evaluating? exp) exp]
 215     [(? variable? exp) (lookup-variable-value exp env)]
 216     [`(quote ,x) x]
 217     [`(set! ,var ,val) (set-variable-value! var (eval val env) env)]
 218     [`(define ,(? (lambda (x) (not (pair? x))) var) ,b) (define-variable! var (eval b env) env)]
 219     [`(define ,(? pair? var) ,b ..1) (define-variable! (car var) (eval (make-lambda (cdr var) b) env) env)]
 220     [`(if ,pred ,consequent ,alternative) (if (true? (eval pred env)) (eval consequent env) (eval alternative env))]
 221     [`(lambda ,parameters ,body ..1) (make-procedure parameters body env)]
 222     [`(begin ,exp ...) (eval-sequence exp env)]
 223     [`(cond ,clauses ...) (eval (cond->if clauses) env)]
 224     [`(let ,bindings ,body ..1) (eval (let->combination exp) env)]
 225     [`(let* ,bindings ,body ..1) (eval (let*->nested-lets exp) env)]
 226     [`(letrec ,bindings ,body ..1) (eval (letrec->combination exp) env)]
 227     [(list f x ...) (apply (eval f env) (list-of-values x env))]
 228     [_ (error "unable to evaluate expression -- EVAL " exp)]))
 229
 230
 231 (define (interpret)
 232   (let loop ([input (read)]
 233              [env the-global-environment])
 234     (let ([output (eval input env)])
 235       (display output)
 236       (loop (read) env))))
 237
 238 (define (t expr)
 239   (let ([t1 (current-inexact-milliseconds)])
 240     (eval expr the-global-environment)
 241     (displayln (- (current-inexact-milliseconds) t1))))